plugins {
    id 'java'
    id 'com.gradleup.shadow' version '8.3.6'
}

group = 'me.asmin.discordbridge'
version = providers.gradleProperty('buildVersion').getOrElse('1.0.0')

repositories {
    mavenCentral()
    maven { url = 'https://repo.papermc.io/repository/maven-public/' }
    maven { url = 'https://repo.lucko.me/' }
}

dependencies {
    compileOnly 'io.papermc.paper:paper-api:1.20.4-R0.1-SNAPSHOT'
    compileOnly 'net.luckperms:api:5.4'
    implementation 'net.dv8tion:JDA:5.2.2'
    implementation 'org.slf4j:slf4j-simple:2.0.16'
}

java {
    toolchain.languageVersion = JavaLanguageVersion.of(17)
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

processResources {
    filesMatching('plugin.yml') {
        expand(version: project.version)
    }
}

shadowJar {
    archiveFileName = "AsminDiscordBridge_${project.version}.jar"
    relocate 'org.slf4j', 'me.asmin.discordbridge.libs.slf4j'
    relocate 'org.jetbrains.annotations', 'me.asmin.discordbridge.libs.annotations'
}

tasks.build {
    dependsOn tasks.shadowJar
}

tasks.jar {
    enabled = false
}